Files
2025-03-20 22:09:07 -07:00

44 lines
1.5 KiB
OpenSCAD

/* https://github.com/BelfrySCAD/BOSL2 */
include <BOSL2/std.scad>
include <BOSL2/rounding.scad>
// Outer length of the tray
outer_length = 180;
// Outer width of the tray
outer_width = 80;
// Outer height of the tray
outer_height = 40;
// Thickness of the walls
wall_thickness = 3; // [2:10]
// Roundness of all outer corners
outer_roundness = 3;
// Roundness of the long bottom inner corners
long_bottom_roundness = 15;
// Roundness of all other inner corners
corner_roundness = 3;
$fn = 80;
assert(corner_roundness >= outer_roundness, "Corner roundness must be greater than or equal outer roundness");
assert(long_bottom_roundness <= 0.75*outer_height, "Bottom roundness must be smaller than 75% of height");
assert(long_bottom_roundness < outer_width/2, "Bottom roundness must be smaller than half the width");
difference() {
cuboid([outer_width,outer_length,outer_height], rounding=outer_roundness, except=TOP, anchor=CENTER);
group() {
translate([0,0,outer_height/2])
cuboid([outer_width-wall_thickness,outer_length-wall_thickness,2*(corner_roundness+wall_thickness)], rounding=corner_roundness, edges="Z");
rotate([-90,0,0])
rounded_prism(square([outer_width-wall_thickness,outer_height-wall_thickness]), height=outer_length-wall_thickness, joint_top=corner_roundness, joint_bot=corner_roundness, joint_sides=[corner_roundness,corner_roundness,long_bottom_roundness,long_bottom_roundness], anchor=CENTER, k=0.9, splinesteps=40);
}
}