Compare commits

..
9 Commits
Author SHA1 Message Date
Stefan Thoss 442f846690 Add Brio tunnel 2026-11-19 20:31:24 -08:00
Stefan Thoss 6cb9540d51 Add drip ledge 2026-11-19 16:08:19 -08:00
Stefan Thoss 4b55efc8e2 Update some measurements 2026-11-04 16:53:06 -08:00
Stefan Thoss 05e5bca54d Add PVC drain end 2026-11-04 16:51:57 -08:00
Stefan Thoss d801554b7c Add multicolor play coin 2026-11-04 16:51:13 -08:00
Stefan Thoss e2e7f075ea Add striped tunnel 2026-11-04 16:50:48 -08:00
Stefan Thoss ee1decf1cb Add ring sizer 2026-07-21 22:06:07 -07:00
Stefan Thoss 84f4e1221b Add siding models 2026-07-21 22:04:21 -07:00
Stefan Thoss e5b6369477 Add sink drain adapter 2026-07-21 22:03:17 -07:00
42 changed files with 210910 additions and 2 deletions
+61
View File
@@ -21,6 +21,8 @@ Model files:
![buffer-stops-v2.png](brio-tracks/buffer-stops-v2.png)
![turntable.png](brio-tracks/turntable.png)
![brio_tunnel.png](brio-tracks/brio_tunnel.png)
![brio_tunnel_curve.png](brio-tracks/brio_tunnel_curve.png)
Documentation:
@@ -35,6 +37,8 @@ Model files:
* train_tracks_generator.scad
* turntable.scad
* ascending_fireplace.scad
* brio_tunnel.scad
* brio_tunnel_curve.scad
## brio-tunnel-block
@@ -43,6 +47,7 @@ Model files:
Model files:
* brio-tunnel-block.scad
* brio-tunnel-block-striped.scad
## c9-lights-roof-clip
@@ -167,6 +172,14 @@ Model files:
* lovevery-coin-raised.scad
* lovevery-coin-stencil.scad
## lovevery-coin-multicolor
![lovevery-coin-multicolor.png](lovevery-coin-multicolor/lovevery-coin-multicolor.png)
Model files:
* lovevery-coin-multicolor.scad
## m5-atom-echo-hsw-mount
![m5-atom-echo-hsw-mount.png](m5-atom-echo-hsw-mount/m5-atom-echo-hsw-mount.png)
@@ -209,6 +222,30 @@ Model files:
* phone-holder-monitor.scad
## pvc-drain-end
![pvc-drain-end.png](pvc-drain-end/pvc-drain-end.png)
Model files:
* pvc-drain-end.scad
## rafter-drip-ledge
![rafter-drip-ledge.png](rafter-drip-ledge/rafter-drip-ledge.png)
Model files:
* rafter-drip-ledge.scad
## ring-sizer
![ring-sizer.png](ring-sizer/ring-sizer.png)
Model files:
* ring-sizer.scad
## server-air-shield
![server-air-shield-525bay.png](server-air-shield/server-air-shield-525bay.png)
@@ -225,6 +262,22 @@ Model files:
* shoe-shelf-wall-mount.scad
## siding-bird-feeder-hanger
![siding-bird-feeder-hanger.png](siding-bird-feeder-hanger/siding-bird-feeder-hanger.png)
Model files:
* siding-bird-feeder-hanger.scad
## siding-light-mount
![siding-light-mount.png](siding-light-mount/siding-light-mount.png)
Model files:
* siding-light-mount.scad
## simple-figurine
![simple-figurine.png](simple-figurine/simple-figurine.png)
@@ -241,6 +294,14 @@ Model files:
* simple-rounded-s-hook.scad
## sink-drain-adapter
![sink-drain-adapter.png](sink-drain-adapter/sink-drain-adapter.png)
Model files:
* sink-drain-adapter.scad
## slim-rpi-wall-holder
![slim-rpi-wall-holder-zero.png](slim-rpi-wall-holder/slim-rpi-wall-holder-zero.png)
File diff suppressed because it is too large Load Diff
File diff suppressed because it is too large Load Diff
File diff suppressed because it is too large Load Diff
Binary file not shown.
Binary file not shown.

After

Width:  |  Height:  |  Size: 25 KiB

+171
View File
@@ -0,0 +1,171 @@
// BRIO-compatible tunnel.
//
// A straight track whose bed is widened into a solid block, carved out by an arched
// bore, with the female/male BRIO connectors kept at the normal height: a solid
// arched profile -> subtract the bore -> subtract the rail wells and the nest ->
// add the plug. The bore floor is flush with the top of the track, so the running
// surface stays a regular BRIO straight and the 45 mm bore gives the stock 2.5 mm
// of lateral clearance on each side.
//
// Construction follows ascending_n_v2.scad: extrude a track profile, cut the nest,
// add the plug.
//
// Driving dimensions: the outer shape (width, `outer_wall` straight height, `total_height`
// crown) and one shell thickness, `ceiling`, which is applied as a parallel offset —
// the bore arc is concentric with the outer barrel and 6 mm inside it everywhere. The
// shell is therefore a true uniform 6 mm: side walls 6 mm, roof 6 mm at the crown and
// 6 mm normal to the arch all the way round.
//
// Everything on the inside follows from that. At the defaults the inner wall springs at
// z 56.5 mm (derived, not a parameter), the bore crown is at z 62 mm, headroom is 50 mm
// at the crown and 44.5 mm at the walls, and the wall->roof junction breaks 62 deg —
// a crisp inner edge like the original wooden tunnel rather than a tangent sweep.
// A deeper, rounder bore would need a shallower barrel or a thicker roof; with a
// parallel shell the two arcs can never disagree about where the curve starts.
//
// Prints upright as modelled, no supports: the roof is a self-supporting vault — at
// 0.2 mm layers each ring of the band rests on ~99% of the ring below it, and the most
// any layer bridges is ~1.3 mm where the vault closes. Loads on the roof run along the
// layers, and the walls are printed under compression, which is the strong direction
// for FDM.
//
// `portal_chamfer` breaks the portal edges all the way round except the underside:
// the bed is a mating face and its bottom corner has to stay square so the male plug
// is bonded along its whole height where it leaves the far portal.
include <train_tracks_generator.scad>
/* https://github.com/BelfrySCAD/BOSL2 */
include <BOSL2/std.scad>
/* [Tunnel] */
// Length of the track body: portal face to portal face, EXCLUDING the connectors.
// 216 = BRIO "D" long straight. The male plug adds 18 mm protruding from one portal
// and the female end is a cavity cut inside the body, so neither is counted here.
// Keep this at or below 238 to stay on a 256 mm bed.
length = 216; // [108:2:238]
// Overall width across the walls
outer_width = 57; // [45:1:150]
// Clear width of the bore; must exceed the 40 mm track to give clearance
inner_width = 45; // [41:0.5:140]
// Height of the crown above the build plate, 12 mm track included
total_height = 68; // [30:1:200]
// Height at which the outer wall stops being straight and the roof barrel starts
outer_wall = 60; // [13:1:190]
// Shell thickness: side walls, and roof measured normal to the arch (uniform)
ceiling = 6; // [2:0.5:20]
// Chamfer breaking the portal edges
portal_chamfer = 1; // [0:0.25:3]
/* [Hidden] */
$fn = 256; // finished part
epsilon = 0.01; // extend cutters past coplanar faces
layer_height = 0.2; // general utility/ornament print; not a Customizer param
arc_steps = 96; // facets per arch, independent of $fn
min_wall = 2; // thinnest wall or roof the Customizer ranges may produce
// ### Derived geometry — the inside is fully determined by the outside + `ceiling`
half_out = outer_width / 2;
half_in = inner_width / 2;
// Bed is flush with the top of the track, so the track stays a working straight.
floor_z = track_height;
// Outer arc through (+-half_out, outer_wall) and (0, total_height)
out_rise = total_height - outer_wall;
out_r = (half_out * half_out + out_rise * out_rise) / (2 * out_rise);
out_z = total_height - out_r; // centre height, shared by both arcs
// Bore arc: concentric, `ceiling` inside the outer one -> constant shell thickness
in_r = out_r - ceiling;
inner_crown = out_z + in_r; // == total_height - ceiling
inner_wall = out_z + sqrt(in_r * in_r - half_in * half_in);
bore_crease = 90 - asin(half_in / in_r); // wall->roof break, degrees
printed_length = length + track_plug_neck_length + track_plug_radius;
assert(inner_width > track_width, "bore must be wider than the 40 mm track");
assert(outer_width - inner_width >= 2 * min_wall, "side walls would be under min_wall thick");
assert(ceiling >= min_wall, "roof would be under min_wall thick");
assert(out_rise > 0, "total_height must be above outer_wall");
assert(out_r >= half_out, "outer arch never reaches the walls: raise the tunnel or narrow it");
assert(in_r >= half_in, "bore arc cannot reach the inner walls: thinner roof, narrower bore or taller tunnel");
assert(inner_wall > floor_z, "bore arch springs below the track bed: taller tunnel or narrower bore");
echo(str("tunnel ", length, " x ", outer_width, " x ", total_height, " mm; uniform shell ",
ceiling, " mm; bore ", inner_width, " mm wide springing at z ",
round(inner_wall * 10) / 10, " (derived), crown at z ", round(inner_crown * 10) / 10,
"; headroom ", round((inner_crown - floor_z) * 10) / 10, " mm at the crown, ",
round((inner_wall - floor_z) * 10) / 10, " mm at the walls, ",
round((inner_width - track_width) * 10) / 10, " mm across for the stock"));
echo(str("outer barrel R", round(out_r * 10) / 10, " springing at z ", outer_wall,
", bore arc R", round(in_r * 10) / 10, ", wall->roof crease ",
round(bore_crease * 10) / 10, " deg"));
echo(str("body ", length, " mm between the portals; ",
round(printed_length * 10) / 10, " mm overall including the protruding plug; ",
printed_length <= 256 ? "fits a 256 mm bed"
: "TOO LONG for a 256 mm bed"));
// Closed outline of a solid arch, in the across/up plane, centred on the track axis:
// straight walls up to where the arc takes over, circular arc over the crown, flat floor.
function arch_outline(half_w, r, z_centre, z_floor) =
let (z_wall = z_centre + sqrt(r * r - half_w * half_w),
amax = asin(half_w / r))
concat(
[[-half_w, z_floor], [-half_w, z_wall]],
[for (i = [0:arc_steps])
let (a = -amax + 2 * amax * i / arc_steps)
[r * sin(a), z_centre + r * cos(a)]],
[[half_w, z_wall], [half_w, z_floor]]
);
// Extrude an arch profile along the track axis, from x = x0 to x = x1, centred on the
// track (the generator puts the track body at y = 0 .. track_width).
module extrude_arch(profile, x0, x1) {
translate([0, track_width / 2, 0])
rotate([90, 0, 90])
translate([0, 0, x0])
linear_extrude(x1 - x0)
polygon(profile);
}
// One object for the slicer
union() {
difference() {
// Solid arched block. The outline is convex, so a hull of the three sections
// lofts them exactly: 45 degree chamfers break the edges of both portal faces.
// The inset sections keep their floor at z = 0 rather than lifting by the
// chamfer width, so the end faces stay full height: lifting it would shave the
// bottom of the bed and leave the root of the male plug standing over a void.
if (portal_chamfer > 0) {
hull() {
extrude_arch(arch_outline(half_out - portal_chamfer,
out_r - portal_chamfer, out_z, 0),
0, portal_chamfer);
extrude_arch(arch_outline(half_out, out_r, out_z, 0),
portal_chamfer, length - portal_chamfer);
extrude_arch(arch_outline(half_out - portal_chamfer,
out_r - portal_chamfer, out_z, 0),
length - portal_chamfer, length);
}
} else {
extrude_arch(arch_outline(half_out, out_r, out_z, 0), 0, length);
}
// Bore: arched vault concentric with the outer barrel, floor flush with the top
// of the track
extrude_arch(arch_outline(half_in, in_r, out_z, floor_z),
-epsilon, length + epsilon);
// Rail wells, along the whole length, so the floor is a working BRIO straight
rotate([90, 0, 90])
translate([0, 0, -epsilon])
linear_extrude(length + 2 * epsilon)
grooves(both_sides = false);
// Female connector in the near portal
install_nest(nest_rotate = 0, length = 0);
}
// Male connector protruding from the far portal, below the bore floor
install_plug(0, length);
}
Binary file not shown.
@@ -0,0 +1,79 @@
// Zebra version of brio-tunnel-block.scad: the block is cut into 8 bands of 5mm
// across its 40mm depth (the dimension that is 40mm tall when the block lies on
// its side) and the bands alternate black/white, so the stripes run over the arch.
// Geometry, chamfering and rounding are identical to brio-tunnel-block.scad; only
// the coloring/slicing is added.
// Colors show in the preview (F5) and in a 3MF export; a plain STL export drops them.
/* https://github.com/BelfrySCAD/BOSL2 */
include <BOSL2/std.scad>
cube_h = 80;
cube_w = 80;
cube_d = 40;
rounding = 2;
oval_cutout_h = 15;
rect_cutout_w = 45;
rect_cutout_h = 65-oval_cutout_h;
// Zebra striping: stripe_n bands of 5mm across the 40mm depth (cube_d),
// alternating between the two stripe colors.
stripe_n = 8;
stripe_w = cube_d / stripe_n; // 5mm
stripe_colors = ["black", "white"];
$fn=150;
// The tunnel block, exactly as in brio-tunnel-block.scad
// (all chamfering and rounding unchanged).
module tunnelblock() {
difference() {
cuboid([cube_w,cube_d,cube_h], rounding=rounding, anchor=[0,0,-1]);
group() {
rotate([90,0,0])
difference() {
cuboid([rect_cutout_w,rect_cutout_h,cube_d], chamfer=-rounding, anchor=[0,-1,0]);
translate([0,rect_cutout_h,0])
cuboid([2*rect_cutout_w,rect_cutout_h,cube_d], anchor=[0,-1,0]);
}
translate([0,0,rect_cutout_h])
resize([0,0,2*oval_cutout_h])
rotate([90,0,0])
cyl(h=cube_d, d=rect_cutout_w, chamfer=-rounding);
}
}
}
// Everything of the block that is *not* between y=y0 and y=y1, as a single
// solid. Cutting the block with one difference() of this union (instead of an
// intersection() with a slab) is what keeps the rounded/chamfered edges at
// y=+/-cube_d/2 intact.
module outside(y0, y1) {
big = 2 * cube_h; // bigger than the block in every direction
union() {
translate([0, (y0-big)/2, cube_h/2])
cube([cube_w + 2*big, big + y0, cube_h + 2*big], center=true);
translate([0, (y1+big)/2, cube_h/2])
cube([cube_w + 2*big, big - y1, cube_h + 2*big], center=true);
}
}
// The block sliced into stripe_n bands along Y, each band colored alternately.
module tunnelblock_striped() {
for (i = [0 : stripe_n-1]) {
y0 = -cube_d/2 + i*stripe_w;
color(stripe_colors[i % len(stripe_colors)])
difference() {
tunnelblock();
outside(y0, y0 + stripe_w);
}
}
}
tunnelblock_striped();
// To render the plain, unstriped block instead, use: tunnelblock();
Binary file not shown.

After

Width:  |  Height:  |  Size: 54 KiB

@@ -0,0 +1,45 @@
coin_d = 2*25.4; // 2"
coin_h = (9/64)*25.4; // 9/64"
edge = 4;
space = 10;
smoothing = 1;
$fn = 100;
module Text(character) {
offset(r=smoothing) offset(r=-2*smoothing) offset(r=smoothing)
text(character, size = 35, font = "Liberation Mono:style=Bold", halign = "center", valign = "center");
}
module CharCoin(character) {
difference() {
color("yellow") cylinder(h = coin_h, d = coin_d);
cylinder(h = coin_h, d = coin_d-2*edge);
}
difference() {
color("gray") cylinder(h = coin_h, d = coin_d-2*edge);
group() {
linear_extrude(coin_h/3)
rotate([0,180,0])
Text(character);
translate([0,0,(2/3)*coin_h+0.001])
linear_extrude(coin_h/3)
Text(character);
}
}
color("yellow") group() {
linear_extrude(coin_h/3)
rotate([0,180,0])
Text(character);
translate([0,0,(2/3)*coin_h+0.001])
linear_extrude(coin_h/3)
Text(character);
}
}
for(num = [0 : 9])
translate([(num%3)*(coin_d+space),-(num/3)*(coin_d+space),0])
CharCoin(str(num));
//CharCoin("");
Binary file not shown.
Binary file not shown.

After

Width:  |  Height:  |  Size: 87 KiB

+39
View File
@@ -0,0 +1,39 @@
/* https://github.com/BelfrySCAD/BOSL2 */
include <BOSL2/std.scad>
pipe_diameter = 48.3;
wall_thickness = 3;
straight_length = 20;
hull_length = 50;
end_height = 20;
end_width = 70;
end_rounding = end_height/2;
additional_offset = 15;
$fn = 150;
difference() {
/* Outside */
group() {
hull() {
cylinder(d=pipe_diameter, h=0.1, anchor=BOTTOM);
up(0.1+hull_length) left(pipe_diameter/2+additional_offset)
cuboid([end_height,end_width,0.1], rounding=end_rounding, edges="Z", anchor=TOP+LEFT);
}
}
/* Inside */
group() {
hull() {
cylinder(d=pipe_diameter-2*wall_thickness, h=0.1, anchor=BOTTOM);
up(0.1+hull_length) left(pipe_diameter/2-wall_thickness+additional_offset)
cuboid([end_height-2*wall_thickness,end_width-2*wall_thickness,0.1], rounding=end_rounding-wall_thickness, edges="Z", anchor=TOP+LEFT);
}
}
}
tube(h=straight_length,od=pipe_diameter,wall=wall_thickness,anchor=TOP);
Binary file not shown.
Binary file not shown.
Binary file not shown.

After

Width:  |  Height:  |  Size: 72 KiB

+150
View File
@@ -0,0 +1,150 @@
/* https://github.com/BelfrySCAD/BOSL2 */
// ============================================================================
// Rafter drip ledge
// ----------------------------------------------------------------------------
// A staple that grips a rafter: a band under the bottom face with a jaw up
// each side face, one deck screw through each jaw. Water running down the
// underside of the rafter reaches the band, crosses it and falls off its
// downhill edge, so it stops trailing along the timber.
//
// The band hangs `thickness` proud of the bottom face and its edge is square.
// That is far more than water can bridge (~3 mm), so the drip is reliable, and
// the band is `thickness` wide along the rafter, which gives the water a
// plateau to fall off rather than a corner to cling to.
//
// The jaws are bored from opposite sides at different heights - a quarter and
// three quarters along the jaw - which is what keeps two long deck screws from
// meeting in the middle of the rafter. With a 1.5" rafter and 1.5" screws the
// tips do overshoot the mid-plane (the echo below prints by how much), so that
// offset is doing real work: do not line the holes up.
//
// Built by sweeping a U, as before:
// x away from the rafter's bottom face; -x is up the side faces
// y across the rafter's width; the timber sits between the jaws
// z along the rafter's length; the band is `thickness` wide there
//
// PRINT LYING EXACTLY AS MODELLED (z up). The part is an extrusion of the U
// section, so every wall is vertical: no supports, no bridged roofs except the
// two screw holes, and the perimeters run all the way round the U, which is
// what carries the load. 54 x 70 mm footprint, 15.5 mm tall.
// ============================================================================
include <BOSL2/std.scad>
include <BOSL2/turtle3d.scad>
/* [Rafter] */
// Width of the face the jaws grip: 1.5" for a rafter stood on its edge
rafter_width = 38.1; // [30:0.1:60]
// How far the jaws run up the side faces (1.5")
jaw_height = 38.1; // [20:0.5:140]
// Band and jaw thickness. Also the radius of the swept outer corners.
thickness = 15; // [8:0.5:25]
// Slip clearance per gripping face - a printed saddle is never a press fit
clearance = 0.4; // [0:0.05:1.5]
/* [Screw] */
// Overall length of the deck screw (1.5" = 38.1)
screw_len = 38.1; // [25:0.5:90]
// Clearance hole through the jaws
hole_d = 6.5; // [4:0.1:9]
// Head diameter that has to bear on the jaw's outer face
head_d = 11; // [6:0.5:20]
/* [Preview] */
// Translucent rafter timber - context only, never part of the print
show_rafter = false;
// Depth of that preview timber up the side faces (5.5")
rafter_depth = 139.7; // [40:1:240]
$fn = 64; // 100 was overkill: only the holes and two small
// corner arcs are curved, and 64 facets is smooth
inset = 0.5; // bead inset of the swept mask, as before
// ---------------------------------------------------------------------------
// Geometry
// ---------------------------------------------------------------------------
// The swept mask sits entirely outside the path, so the jaws' inner faces land
// exactly `gap` apart - measured off the exported mesh, not assumed. Asking for
// the rafter width plus clearance is therefore what you get.
gap = rafter_width + 2 * clearance;
wall = thickness + 2 * inset; // jaw thickness the screw passes
// through, measured 16.0
path = turtle3d(["move", jaw_height,
"arcright", inset, 90,
"move", gap,
"arcright", inset, 90,
"move", jaw_height]);
// Screws at a quarter and three quarters along the jaw, diagonally opposed.
hole_lo_x = 0.25 * jaw_height; // near the jaw tips
hole_hi_x = 0.75 * jaw_height;
stagger = hole_hi_x - hole_lo_x; // how far apart the two screws
// end up, up the side faces
hole_z = (thickness + 2 * inset) / 2; // mid band, not mid mask
// ---------------------------------------------------------------------------
// Does the screw actually work? Checked, not hoped.
// ---------------------------------------------------------------------------
// The head bears on the jaw's outer face, so only screw_len - wall of the screw
// reaches the wood.
penetration = screw_len - wall;
tip_overshoot = penetration - rafter_width / 2; // past the rafter's mid-plane
edge_margin = hole_lo_x - hole_d / 2; // plastic outside the top hole
corner_margin = jaw_height - hole_hi_x - hole_d / 2;
assert(gap >= wall + 6,
"jaws too thin for this rafter: a screw hole would break into the far jaw");
assert(head_d >= hole_d + 3,
str("a ", head_d, " mm head has nothing to bear on around a ", hole_d,
" mm hole: needs at least 1.5 mm of bearing all round"));
assert(penetration >= 12,
"too little screw reaches the timber: raise screw_len or drop thickness");
assert(edge_margin >= 3 && corner_margin >= 3,
"the screw holes are too close to the jaw end or to the band: raise jaw_height");
assert(stagger >= hole_d + 4,
"the two holes are too close together: raise jaw_height so they can be staggered further");
assert(tip_overshoot <= -2 || stagger >= head_d + 4,
"the screws would meet in the middle: offset them further, or shorten them");
echo(str("fit: jaws ", fmt(gap), " mm apart for a ", fmt(rafter_width),
" mm rafter (", fmt(clearance), " mm per face), band ", fmt(wall),
" mm proud of the bottom face"));
echo(str("screw: ", fmt(screw_len), " mm length less the ", fmt(wall),
" mm jaw = ", fmt(penetration), " mm in the timber, tip ",
tip_overshoot > 0 ? str("overshoots the mid-plane by ", fmt(tip_overshoot))
: str(fmt(-tip_overshoot), " short of the mid-plane"),
", holes ", fmt(stagger), " mm apart vertically"));
echo(str("print: lying flat as modelled, ", fmt(jaw_height + wall), " x ",
fmt(gap + 2 * wall), " mm footprint x ", fmt(wall),
" mm tall, no supports; the two screw holes bridge ", fmt(wall), " mm"));
if (tip_overshoot > 0)
echo(str("NOTE: the screws pass each other's centreline - the ", fmt(stagger),
" mm vertical offset is what stops them meeting. Keep the jaws square ",
"to the timber when screwing on."));
function fmt(v) = round(v * 10) / 10;
// ---------------------------------------------------------------------------
// Part
// ---------------------------------------------------------------------------
difference() {
path_sweep(mask2d_roundover(r = thickness, inset = inset), path);
// Cutters long enough to leave nothing behind: an 0.5 mm skin of plastic
// left on the far side of a jaw stops the screw head seating.
// The swept mask sits entirely outside the path, so each jaw's material is
// on the far side of its path line, away from the timber (measured: jaw 1
// spans y -0.5..15.5 about a path at y = 0, jaw 2 spans -55.4..-39.4 about a
// path at y = -gap). Centring a cutter on the path, or running one right
// across the part, drills one jaw properly and only nicks the other - which
// is what the original did, leaving a blind hole.
for (j = [[hole_lo_x, 0, 1], // jaw, its path y, which way it grows
[hole_hi_x, -gap, -1]])
move([j[0], j[1] + j[2] * (wall / 2 - inset), hole_z])
ycyl(d = hole_d, h = wall + 4);
}
if (show_rafter)
color("saddlebrown", 0.35)
move([jaw_height - inset - rafter_depth / 2, -gap / 2 - inset, hole_z])
cuboid([rafter_depth, rafter_width, 120]);
File diff suppressed because it is too large Load Diff
File diff suppressed because it is too large Load Diff
File diff suppressed because it is too large Load Diff
Binary file not shown.
Binary file not shown.

After

Width:  |  Height:  |  Size: 56 KiB

+44
View File
@@ -0,0 +1,44 @@
include <BOSL2/std.scad>
/*
* Chamfered Ring Module with Embedded Number
*
* @param id Inner diameter in mm (Default: 15.7)
* @param h Height in mm (Default: 3.9)
* @param thickness Wall thickness in mm (Default: 2.4)
* @param chamfer_size Size of the 45-degree chamfer in mm (Default: 0.5)
* @param ring_num The number (or text) to engrave (Default: "5")
* @param font_size Height of the number in mm (Default: 2.5)
* @param embed_depth How deep the number cuts into the ring in mm (Default: 0.5)
*/
module chamfered_ring(
id = 15.7,
h = 3.9,
thickness = 2.4,
chamfer_size = 0.5,
ring_num = "5",
font_size = 2.5,
embed_depth = 0.55
) {
od = id + (thickness * 2);
difference() {
tube(id = id, od = od, h = h, chamfer = chamfer_size);
rotate([90, 0, 0])
translate([0, 0, (od/2) - embed_depth])
linear_extrude(embed_depth + 1)
text(
text = str(ring_num),
size = font_size,
font = "Liberation Mono:style=Bold",
valign = "center",
halign = "center"
);
}
}
$fn = 200;
//chamfered_ring(id = 15.3, ring_num = "4.5");
chamfered_ring(id = 15.7, ring_num = "5");
Binary file not shown.
@@ -3,9 +3,9 @@ include <BOSL2/std.scad>
$fn = 100;
radius_back = 11;
radius_back = 6.5;
radius_front = 11;
radius_hole = 2.5;
radius_hole = 3;
assert(radius_front >= radius_back);
Binary file not shown.
Binary file not shown.

After

Width:  |  Height:  |  Size: 76 KiB

@@ -0,0 +1,63 @@
/* https://github.com/BelfrySCAD/BOSL2 */
include <BOSL2/std.scad>
include <BOSL2/screws.scad>
lap_height = 127;
lap_depth = 9;
wall_width = 500;
hanger_length = 125;
hanger_diag_length = sqrt(2)*hanger_length;
hanger_width = 20;
hanger_thickness = 7;
hanger_overlap = 20;
hanger_rounding = 2;
hook_hole_diameter = 5;
$fn = 120;
module LapPlank() {
// Define the triangular profile for the siding
// We use a polygon for the wedge shape
path = [[0, 0], [lap_depth, 0], [0, lap_height], [0, 0]];
// Sweep the profile across the width of the wall
linear_extrude(wall_width) polygon(path);
}
module BackPattern() {
rotate([90,0,0])
translate([0,-lap_height/2,-wall_width/2])
ycopies(lap_height, l=wall_width)
LapPlank();
}
module Hanger() {
/* Main beam */
right(lap_depth)
cuboid([hanger_length+hanger_overlap,hanger_width,hanger_thickness], rounding=hanger_rounding, anchor=LEFT);
/* Diag beam */
up(hanger_length) right(lap_depth)rotate([0,45,0])
cuboid([hanger_diag_length,hanger_width,hanger_thickness], rounding=hanger_rounding, anchor=LEFT);
/* Back beam */
down(hanger_overlap)
cuboid([hanger_thickness+lap_depth,hanger_width,hanger_length+2*hanger_overlap], rounding=hanger_rounding, anchor=LEFT+BOTTOM);
}
difference() {
Hanger();
group() {
BackPattern();
translate([hanger_thickness+lap_depth,0,-(hanger_thickness/2+hanger_overlap)/2]) rotate([0,90,0]) screw_hole("#8,2",head="flat",anchor=TOP);
translate([hanger_thickness+lap_depth,0,hanger_length+(hanger_thickness/2+hanger_overlap)/2]) rotate([0,90,0]) screw_hole("#8,2",head="flat",anchor=TOP);
/* Hook hole */
right(hanger_length+hanger_overlap)
zcyl(d=hook_hole_diameter, h=hanger_thickness);
}
}
Binary file not shown.
Binary file not shown.
Binary file not shown.
Binary file not shown.

After

Width:  |  Height:  |  Size: 37 KiB

@@ -0,0 +1,47 @@
include <BOSL2/std.scad>
lap_height = 127;
lap_depth = 9;
wall_width = 500;
ring_outer = 120;
ring_inner = 60;
ring_thickness = lap_depth + 2;
ring_offset = -15; // -15 for left light, -55 for right light
screw_diameter = 6.5;
screw_center_offset = 45;
$fn = 200;
module lap_plank() {
// Define the triangular profile for the siding
// We use a polygon for the wedge shape
path = [[0, 0], [lap_depth, 0], [0, lap_height], [0, 0]];
// Sweep the profile across the width of the wall
linear_extrude(wall_width) polygon(path);
}
module back_pattern() {
translate([0,-lap_height/2,-wall_width/2])
ycopies(lap_height, l=wall_width)
lap_plank();
}
difference() {
translate([0,ring_offset,0])
difference() {
xcyl(l=ring_thickness, d=ring_outer, anchor=LEFT);
xcyl(l=ring_thickness, d=ring_inner, anchor=LEFT);
}
group() {
back_pattern();
/* screw holes */
translate([0,ring_offset,0]) rotate([45,0,0]) group() {
translate([0,0,screw_center_offset]) xcyl(d=screw_diameter, l=4*ring_thickness);
translate([0,0,-screw_center_offset]) xcyl(d=screw_diameter, l=4*ring_thickness);
}
}
}
Binary file not shown.
Binary file not shown.

After

Width:  |  Height:  |  Size: 42 KiB

@@ -0,0 +1,15 @@
/* https://github.com/BelfrySCAD/BOSL2 */
include <BOSL2/std.scad>
outer_diameter = 48.5;
inner_diameter = 32;
length = 20;
lip_thickness = 4.4;
lip_height = 2;
$fn = 150;
up(lip_height)
tube(h=length, od=outer_diameter, id=inner_diameter, anchor=BOT);
tube(h=lip_height, od=outer_diameter+2*lip_thickness, id=inner_diameter, anchor=BOT);
Binary file not shown.